apply plugin: 'com.android.application'
apply plugin: 'com.neenbedankt.android-apt'

/*
 * Copyright (C) 2016 Phillip Hsu
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

// =============================================================================
// https://developer.android.com/studio/publish/app-signing.html#secure-shared-keystore

// Create a variable called keystorePropertiesFile, and initialize it to your
// keystore.properties file, in the rootProject folder.
def keystorePropertiesFile = rootProject.file("keystore.properties")

// Initialize a new Properties() object called keystoreProperties.
def keystoreProperties = new Properties()

// Load your keystore.properties file into the keystoreProperties object.
keystoreProperties.load(new FileInputStream(keystorePropertiesFile))

// =============================================================================

android {
    signingConfigs {
        config {
            keyAlias keystoreProperties['keyAlias']
            keyPassword keystoreProperties['keyPassword']
            storeFile file(keystoreProperties['storeFile'])
            storePassword keystoreProperties['storePassword']
        }
    }
    compileSdkVersion 24
    buildToolsVersion "24.0.2"
    defaultConfig {
        applicationId 'com.philliphsu.clock2'
        minSdkVersion 19
        targetSdkVersion 24
        versionCode 111
        versionName "1.1.1"
        // Disabled for now because we're not ready to
        // completely port over to vector drawables
//        vectorDrawables.useSupportLibrary = true
    }
    buildTypes {
        release {
            // https://developer.android.com/studio/build/shrink-code.html#shrink-code
            //
            // Proguard is disabled, because it seems like it is removing
            // ButterKnife generated code and I don't know how to fix it...
            minifyEnabled false
            // "'proguard-android-optimize.txt' includes the same ProGuard rules
            // [as 'proguard-android.txt'], but with other optimizations that
            // perform analysis at the bytecode level—inside and across methods—
            // to reduce your APK size further and help it run faster."
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            signingConfig signingConfigs.config
        }
        debug {
            applicationIdSuffix ".debug"
        }
    }
    productFlavors {
    }
}

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    testCompile 'junit:junit:4.12'
    testCompile 'org.mockito:mockito-core:1.10.19'
    // TODO: delete, not in use
    testCompile 'org.robolectric:robolectric:3.0'
    provided 'com.google.auto.value:auto-value:1.2'
    apt 'com.google.auto.value:auto-value:1.2'
    compile 'com.android.support:appcompat-v7:24.2.0'
    compile 'com.android.support:design:24.2.0'
    compile 'com.android.support:support-v4:24.2.0'
    compile 'com.android.support:recyclerview-v7:24.2.0'
    compile 'com.android.support:gridlayout-v7:24.2.0'
    compile 'com.android.support:cardview-v7:24.2.0'
    compile 'com.jakewharton:butterknife:7.0.1'
    compile project(":bottomsheetpickers-release")
}